dc/sas/sasjs/services/public/getchangeinfo.sas

/**
  @file getchangeinfo.sas
  @brief Returns the details for an approval diff
  @details

  <h4> SAS Macros </h4>
  @li dc_assignlib.sas
  @li mf_getengine.sas
  @li mf_getuser.sas
  @li mf_nobs.sas
  @li mp_abort.sas
  @li mpe_accesscheck.sas
  @li mpe_getgroups.sas

  <h4> Service Inputs </h4>
  <h5> sascontroltable </h5>
  @li table table ID or LOAD_REF used to uniquely identify a staged change

  <h4> Service Outputs </h4>

  <h5> work.jsparams </h5>
  Mainly sourced from MPE_SUBMIT plus some extra cols:

  @li LIB_ENGINE Library engine
  @li allow_restore YES if a user can restore, else NO
  @li REASON reason why a restore is / is no possible

  @version 9.2
  @author 4GL Apps Ltd
  @copyright 4GL Apps Ltd.  This code may only be used within Data Controller
    and may not be re-distributed or re-sold without the express permission of
    4GL Apps Ltd.

**/

%mpeinit()

%let table=;
data _null_;
  set SASControlTable;
  call symputx('table',table);
run;

%dc_assignlib(WRITE,%scan(&table,1,.))

%let max_ver_dttm=0;

data APPROVE1;
  set &mpelib..mpe_submit
    (rename=(SUBMITTED_ON_DTTM=submitted_on REVIEWED_ON_DTTM=REVIEWED_ON));
  where TABLE_ID="&TABLE";
  TABLE_NM=cats(base_lib,'.',base_ds);
  BASE_TABLE=table_nm;
  call symputx('base_lib',base_lib);
  call symputx('base_ds',base_ds);
  REVIEWED_ON_DTTM=put(reviewed_on,datetime19.);
  SUBMITTED_ON_DTTM=put(submitted_on,datetime19.);
run;

/**
  * Check if user has basic access permission to RESTORE the table
  */
%put checking access;

%global allow_restore reason;
%let allow_restore=NO;
%let reason=NOTFOUND;

%macro access_check();

  /* grab user groups */
  %let user=%mf_getuser();
  %mpe_getgroups(user=&user,outds=work.groups)

  /* check if user is admin */
  %let is_admin=0;
  proc sql;
  select count(*) into: is_admin from work.groups where groupname="&MPEADMINS";

  %if &is_admin>0 %then %do;
    %let allow_restore=YES;
    %let reason=IS ADMIN;
    %return;
  %end;

  /* check if user has basic access */
  %mpe_accesscheck(&base_lib..&base_ds,outds=work.access_check
    ,user=&user
    ,access_level=EDIT
  )
  %if %mf_nobs(access_check)=0 %then %do;
    %let allow_restore=NO;
    %let reason=No access in MPE_TABLES;
    %return;
  %end;

  /* check if user has column level security rules */
  proc sql;
  create table work.cls_rules as
    select *
    from &mpelib..mpe_column_level_security
    where &dc_dttmtfmt. lt tx_to
      and CLS_SCOPE in ("EDIT",'ALL')
      and CLS_ACTIVE=1
      and upcase(CLS_GROUP) in (select upcase(groupname) from work.groups)
      and CLS_LIBREF="%upcase(&base_lib)"
      and CLS_TABLE="%upcase(&base_ds)";
  %if %mf_nobs(work.cls_rules)>0 %then %do;
    %let allow_restore=NO;
    %let reason=User has restrictions in MPE_COLUMN_LEVEL_SECURITY;
    data _null_;
      set work.cls_rules;
      putlog (_all_)(=);
      if _n_>5 then stop;
    run;
    %return;
  %end;

  /* check if user has row level security rules */
  proc sql;
  create table work.rls_rules as
    select *
    from &mpelib..mpe_row_level_security
    where &dc_dttmtfmt. lt tx_to
      and rls_scope in ("EDIT",'ALL')
      and upcase(rls_group) in (select upcase(groupname) from work.groups)
      and rls_libref="&base_lib"
      and rls_table="&base_ds"
      and rls_active=1;
  %if %mf_nobs(work.rls_rules)>0 %then %do;
    %let allow_restore=NO;
    %let reason=User has restrictions in MPE_ROW_LEVEL_SECURITY;
    data _null_;
      set work.rls_rules;
      putlog (_all_)(=);
      if _n_>5 then stop;
    run;
    %return;
  %end;
  %else %do;
    %let allow_restore=YES;
    %let reason=CHECKS PASSED;
    %return;
  %end;
%mend access_check;

%access_check();


data work.jsParams;
  set approve1;
  LIB_ENGINE="%mf_getEngine(&base_lib)";
  allow_restore="&allow_restore";
  REASON="&reason";
run;

%mp_abort(iftrue= (&syscc ne 0)
  ,mac=&_program..sas
  ,msg=%str(syscc=&syscc)
)

%webout(OPEN)
%webout(OBJ,jsParams)
%webout(CLOSE)


%mpeterm()