dc/sas/sasjs/services/editors/restore.test.2.sas

/**
  @file
  @brief testing restore of a change to a special missing value

  @details A cell holding a special missing (._ .A-.Z) and changed to an
    ordinary number must be reverted to that special missing. mp_stripdiffs
    writes the old value into a generated UPDATE statement, and PUT drops the
    leading period of a special missing, so the statement used to be
    "set SOME_BESTNUM =_" - which PROC SQL reads as a column name.

  <h4> SAS Macros </h4>
  @li mp_assert.sas
  @li mx_execute.sas

**/

%let _program=&appLoc/services/editors/restore;

/* seed the base table with a special missing - the audit stores whatever the
  base holds, so this is the value the revert has to write back */
proc sql noprint;
update &dclib..mpe_x_test set some_bestnum=._
  where primary_key_field=3;
quit;

/**
  * load 1 - change that cell to an ordinary number
  */
data work.sascontroltable;
  action='LOAD';
  message="special missing prep";
  libds="&dclib..MPE_X_TEST";
  output;
  stop;
run;

data work.jsdata;
  set &dclib..mpe_x_test(where=(primary_key_field=3)
    rename=(some_date=dt2 SOME_DATETIME=dttm2 SOME_TIME=tm2)
  );
  /* the adapter sends these as strings */
  some_date=put(dt2,date9.);
  SOME_DATETIME=put(dttm2,datetime19.);
  some_time=put(tm2,time.);
  drop dt2 dttm2 tm2;
  _____DELETE__THIS__RECORD_____='No';
  some_bestnum=42;
run;

%mx_execute(&appLoc/services/editors/stagedata,
  viyacontext=&defaultcontext,
  inputdatasets=work.jsdata work.sascontroltable,
  outlib=web1,
  mdebug=&sasjs_mdebug
)

%let status=0;
data _null_;
  set web1.sasparams;
  if status='SUCCESS' then call symputx('status',1);
  call symputx('dsid',dsid);
run;
%mp_assert(
  iftrue=(&status=1 and &syscc=0),
  desc=Checking the special missing change was staged,
  outds=work.test_results
)

data work.sascontroltable;
  ACTION='APPROVE_TABLE';
  TABLE="&dsid";
  DIFFTIME="%sysfunc(datetime())";
  output;
  stop;
run;
%mx_execute(&appLoc/services/auditors/postdata,
  viyacontext=&defaultcontext,
  inputdatasets=work.sascontroltable,
  outlib=web3,
  outref=wb3,
  mdebug=&sasjs_mdebug
)

%let status=0;
data _null_;
  set web3.apparams;
  if response='SUCCESS!' then call symputx('status',1);
run;
%mp_assert(
  iftrue=(&status=1 and &syscc=0),
  desc=Checking the change was approved,
  outds=work.test_results
)

/* the load reference to revert */
%let loadref=0;
data _null_;
  set &dclib..mpe_submit end=last;
  if last then call symputx('loadref',table_id);
run;

/**
  * revert it - the old value in the diff is the special missing
  */
data work.restore_in;
  load_ref="&loadref";
  output;
  stop;
run;
%mx_execute(&_program,
  viyacontext=&defaultcontext,
  inputdatasets=work.restore_in,
  outlib=web1,
  mdebug=&sasjs_mdebug
)

%let newref=0;
data _null_;
  set web1.restore_out;
  call symputx('newref',loadref);
run;
%mp_assert(
  iftrue=(&newref ne 0 and &syscc=0),
  desc=Checking the revert was submitted,
  outds=work.test_results
)

/* approve the reversion */
data work.sascontroltable;
  ACTION='APPROVE_TABLE';
  TABLE="&newref";
  DIFFTIME="%sysfunc(datetime())";
  output;
  stop;
run;
%mx_execute(&appLoc/services/auditors/postdata,
  viyacontext=&defaultcontext,
  inputdatasets=work.sascontroltable,
  outlib=web3,
  outref=wb3,
  mdebug=&sasjs_mdebug
)

%let status=0;
data _null_;
  set web3.apparams;
  if response='SUCCESS!' then call symputx('status',1);
run;
%mp_assert(
  iftrue=(&status=1 and &syscc=0),
  desc=Checking the reversion was approved,
  outds=work.test_results
)

/* and the cell is back to the special missing, not a number and not blank */
%let spmcheck=0;
data _null_;
  set &dclib..mpe_x_test(where=(primary_key_field=3));
  if some_bestnum=._ then call symputx('spmcheck',1);
  putlog some_bestnum=;
run;
%mp_assert(
  iftrue=(&spmcheck=1),
  desc=Checking the special missing was restored,
  outds=work.test_results
)

/* put the fixture back as makedata left it */
proc sql noprint;
update &dclib..mpe_x_test set some_bestnum=44
  where primary_key_field=3;
quit;